home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
CRS
/
crs53.d81
/
polldevs.prg
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2009-10-10
|
1KB
|
29 lines
0 REM * POLL DEVS.BAS BY DOUG COTTON * * (C)1991 CREATIVE MICRO DESIGNS *
1 PRINT"[147]";:DIM DN$(6),LB(6),HB(6),CK$(6),NB(6),TY$(7)
5 FORI=1TO6:READDN$(I),LB(I),HB(I),CK$(I),NB(I),TY$(I):NEXT:READTY$(7)
10 FORI=8TO29
20 OPEN15,I,15:CLOSE15
30 IFST=0THENPRINT"DEVICE"I;:GOSUB70
40 NEXT
50 END
60 DATA "CMD HD",164,254,"HD",2," ( NATIVE"
61 DATA "RAMDRIVE",164,254,"RD",2," ( 1541"
62 DATA "RAMLINK",164,254,"RL",2," ( 1571"
63 DATA "1581",233,166,"8",1," ( 1581"
64 DATA "1571",198,229,"7",1," ( 1581 CP/M"
65 DATA "1541",198,229,"4",1," ( PRINT BUFFER"," ( FOREIGN"
70 OPEN15,I,15
80 FORJ=1TO6
90 PRINT#15,"M-R"CHR$(LB(J))CHR$(HB(J))CHR$(NB(J))
100 GET#15,X$:IFNB(J)=2THENGET#15,Y$:X$=X$+Y$
110 IFX$=CK$(J)THENPRINTDN$(J);:T=J:J=6:IFT<4THENGOSUB150
120 NEXT
130 PRINT:CLOSE15
140 RETURN
150 PRINT#15,"G-P"CHR$(255)
160 GET#15,T$:T=ASC(T$+CHR$(0))
170 PRINTTY$(T);
180 GET#15,Z$,PN$:PN=ASC(PN$+CHR$(0))
190 PRINT" #";PN;")";
200 RETURN